\\ Included here are the commands needed for the
\\ computations in the paper
\\ "On a Shimura Curve that is a Counterexample to the Hasse Principle"
\\ by Siksek & Skorobogatov
\\ The reader is meant to run gp and copy and paste
\\ the commands to verify the computation
\\ The following inputs the file PariRoutines
\r PariRoutines.gp
\\ w will equal \sqrt{-13}
w=quadgen(-13*4)
g=-(3*u^2+12*u+13)*(u^2+12*u+39)
\\ We will represent the curve Y: v^2=g(u) (Equation 2 in paper)
\\ by a vector of coefficients [a,b,c,d,e]
Y=Vec(g)
P_0=[(-39+4*w)/7,(260-120*w)/49]
\\ A check to see if the point P_0 is on the quartic curve Y
isOnQuartic(Y,P_0)
\\ The following command generates a quintuple of the form
\\ Quint=[Y,P_0,ell,Phi,Psi]
\\ where Y, P_0 are as above
\\ ell is a Weierstrass elliptic curve,
\\ Phi: Y ----> ell taking P_0 to infinity
\\ Psi is the inverse map
\\ Here we are thinking of Y as an equation in u,v (as in the paper)
\\ and ell=[a1,a2,a3,a4,a6,....] as an equation in x,y :
\\ y^2+a1*x*y+a3*y=x^3+a2*x^2+a4*x+a6
\\ Thus Phi=[x,y] where x,y are given in terms of u,v
\\ and Psi=[u,v] where u,v are given in terms of x,y
Quint=quarToEll2(Y,P_0)
\\ The following changes of coordinates simplify the elliptic curve
\\ while updating the maps Phi,Psi so that the above remain true
Quint=VeryShort(Quint)
Quint=ChangCoord(Quint,[2/3,0,0,0])
Quint=ChangCoord(Quint,[1,-3,0,0])
Quint=ChangCoord(Quint,[3,0,0,0])
\\ Now Quint=[Y,P_0,E,Phi,Psi] where E is the elliptic
\\ curve y^2=(x-10)*(x+3)*(x+6) given in the paper
\\ Phi: Y ---> E is the birational map taking P_0 to infinity
\\ and Psi is the inverse map
\\ Below are the points S_1,S_2,S_3 of Lemma 2.1
\\ that form a basis for E(K)
S_1=[10,0]
S_2=[-3,0]
S_3=[-14/13,(480/169)*w]
E=Quint[3]
ellisoncurve(E,S_1)
ellisoncurve(E,S_2)
ellisoncurve(E,S_3)
\\ We want now to check that S_1, S_2, S_3 are
\\ independent in E(K) where $K=\Q(\sqrt{-13})$
\\ as claimed in the proof of Lemma 2
\\ We will do this using the injective homomorphism
\\ E(K)/2E(K) ----> K^*/(K^*)^2 \times K^*/(K^*)^2 \times K^*/(K^*)^2
\\ [x,y] ----> [x-10,x+3,x+6] mod squares
\\ with suitable patching for points of order 2
\\ (See Cassels, Lectures on Elliptic Curves, page 67)
\\ We will do this calculation by hand!
\\ Note S_1 ---> [ ? , 13 , 16] = [? , -1 , 1] = [-1, -1, 1]
\\ S_2 ---> [-13 , ? , 3] = [1 , ? , 3] = [1 , 3 , 3]
\\ S_3 ---> [-144/13 , 25/13, 64/13] = [1,-1,-1]
\\ Now simply note that [-1,-1,1] , [1,3,3], [1,-1,-1]
\\ are independent modulo K^*^2
\\ The command MapEllToQuar maps a point on E
\\ to a point on Y
\\ P_1, P_2, P_3 are the points in paper
\\ mentioned just after Lemma 2
P_1=MapEllToQuar(Quint,S_1)
P_2=MapEllToQuar(Quint,S_2)
P_3=MapEllToQuar(Quint,S_3)
\\ The following check that P_1,P_2,P_3
\\ really are on the quartic Y
isOnQuartic(Y,P_1)
isOnQuartic(Y,P_2)
isOnQuartic(Y,P_3)